Найти класс отображающий расшифровку номенклатуры

[tolstjak]

Цитата:

Сообщение от S.Kuskov

Какое-то странное у вас требование к отчёту. Неужели нужно показыват именно текст всплывающей подсказки? Сомневаюсь, что требование звучит именно так. Скорее необходимо показывать информацию, которая именно на данный момент совпадает с текстом подсказки. Представьте что какие-то модификации или переход на следующую версию изменят алгоритм отображения подсказки. Как должен вести себя ваш отчёт?

Прошу прощения, но требование к отчету нормальные. А подход к его формированию следующий: чем меньше кода написано. тем лучше. Если можно использовать уже имеющееся в системе, это надо делать. А пример с номенклатуром, может быть не совсем удачным. Посмотрите на подсказку на форме проводок номенклатурного справочника, когда курсор подводите с полю в столбце Код. Хотя надо признать, что этот метод (toolTipRecord() ) хорош, но в данном отчете не пригодился. Клиентам как всегда захотелось увидеть больше....

[Gustav]

Цитата:

Сообщение от tolstjak

А подход к его формированию следующий: чем меньше кода написано. тем лучше.

Мне кажется, это не совсем тот случай, когда надо экономить на коде. Ведь текст toolTipRecord может быть легко воспроизведен с помощью несложного шаблона для функции strFmt:

{
    InventTable inventTable;
    ;
    select firstonly inventTable;
    info( inventTable.toolTipRecord());
    info( strFmt('Номенклатура: %1, %2', inventTable.ItemId, inventTable.ItemName));
}

Т.е. для включения в отчет эквивалентной информации имеем два обращения к табличной переменной (inventTable.ItemId, inventTable.ItemName) вместо одного (inventTable.toolTipRecord). Не думаю, что это стоить считать лишним кодом. Зато два поля вы можете поместить в разные поля отчета, сделав его гораздо гибче, чем всё в одном "флаконе", к тому же с избыточным словом "Номенклатура"...

[tolstjak]

Цитата:

Сообщение от Gustav

Мне кажется, это не совсем тот случай, когда надо экономить на коде. ..... Зато два поля вы можете поместить в разные поля отчета, сделав его гораздо гибче, чем всё в одном "флаконе", к тому же с избыточным словом "Номенклатура"...

Возможно Вы правы, но взгляните на подсказку на форме проводок номенклатурного справочника, там такого кода без использования tool..... будет значительно больше. И разумеется я никому не навязываю свое мнение.

[Gustav]

Цитата:

Сообщение от tolstjak

Посмотрите на подсказку на форме проводок номенклатурного справочника, когда курсор подводите с полю в столбце Код.

Цитата:

Сообщение от tolstjak

...там такого кода без использования tool..... будет значительно больше

Взглянул. Интересно, спасибо. Не понял, как делается - в super toolTip'а не пустили, а также как этим можно просто воспользоваться, например, в отчете? Не из формы же читать всякий раз... Хотя чисто технически возможно:

static void Job_ToolTipViaFormControl(Args _args)
{
    Args            args;
    FormRun         formRun;
    InventTrans     inventTrans;
    ;

    inventTrans.clear();

    // последовательно раскомментируем записи по одной и позапускаем
    select firstonly inventTrans where inventTrans.TransType == InventTransType::Purch;
    //select firstonly inventTrans where inventTrans.TransType == InventTransType::InventTransaction;
    //select firstonly inventTrans where inventTrans.TransType == InventTransType::InventTransfer;

    args = new Args(formstr(InventTrans));
    args.record(inventTrans);

    formRun = classFactory.formRunClass(args);
    formRun.init();
    //formRun.design().visible(false);  // раскомментируй для невидимости формы
    formRun.run();

    box::info(formRun.design().controlName('InventTrans_TransRefId').toolTip());

    formRun.wait();     // ЗАкомментируй для невидимости формы
    //formRun.close();  // раскомментируй для невидимости формы
}

Попробовал исполнить по аналогии - что-то получилось, привожу ниже. В switch прописал только те типы движения, которые встречаются у нас в системе. При желании список легко расширяется.

static void Job_ToolTipImitation(Args _args)
{
    // имитация текста всплывающей подсказки на поле Код в форме складских проводок

    InventTrans inventTrans;
    Common      common;
    str         ourToolTipText;
    DictTable   dictTable;
    ;

    // последовательно раскомментируем записи по одной и позапускаем
    select firstonly inventTrans where inventTrans.TransType == InventTransType::Purch;
    //select firstonly inventTrans where inventTrans.TransType == InventTransType::InventTransaction;
    //select firstonly inventTrans where inventTrans.TransType == InventTransType::InventTransfer;

    switch (inventTrans.TransType)
    {
        case InventTransType::Purch : // Закупка
            common = PurchTable::find(inventTrans.TransRefId);
            break;

        case InventTransType::InventTransaction : // Проводка
        case InventTransType::InventTransfer    : // Перенос
            common = InventJournalTable::find(inventTrans.TransRefId);
            break;

        default:
            box::stop('Непредусмотренный случай.');
            return;
    }

    // создадим через strFmt нашу собственную подсказку
    dictTable = new DictTable(common.TableId);
    ourToolTipText = strFmt('%1: %2, %3',
                        new DictField(common.TableId, dictTable.titleField1()).label(), // Закупка   // Журнал
                        common.(dictTable.titleField1()),                               // PurchId   // JournalId
                        common.(dictTable.titleField2()));                              // PurchName // Description

    // для сравнения отобразим обе версии подсказки друг под другом
    box::info(strFmt('%1\n%2', common.toolTipRecord(),  // фирменная
                               ourToolTipText ));       // самопальная

В общем, кода - не смертельное количество. Хотя и не 2 строки

[AndyD]

Цитата:

Сообщение от Gustav

Взглянул. Интересно, спасибо. Не понял, как делается - в super toolTip'а не пустили, а также как этим можно просто воспользоваться, например, в отчете? Не из формы же читать всякий раз... Хотя чисто технически возможно:

Не надо так сложно
Есть метод ToolTipField()

...
select firstonly inventTrans where inventTrans.TransType == InventTransType::Purch;
info(inventTrans.ToolTipField(fieldNum(InventTrans, TransRefId)));

[Gustav]

Цитата:

Сообщение от AndyD

Не надо так сложно
Есть метод ToolTipField()

...
select firstonly inventTrans where inventTrans.TransType == InventTransType::Purch;
info(inventTrans.ToolTipField(fieldNum(InventTrans, TransRefId)));

Да уж...И в этом случае tolstjak абсолютно прав, и проще разобрать на две колонки текст столь легко полученного toolTip'а, чем сначала определять, из какой же таблицы надо получить 2 поля...
В общем, I'm impressed!