Сохранение параметров отчёта

[Paul_ST]

Добрый день! Есть класс - наследник RunBaseBatch. В методе new() генерируется query, по которому создаётся queryRun. Данный объект возвращается методом queryRun(). В методе run() обрабатывается запрос - цикл while queryRun.next ...
Всё работает замечательно. Только - при повторном запуске класса последние введённые параметра запроса не сохраняются, но если нажать кнопку "Выбор", то в окне запроса они появляются и при закрытии окна запроса переходят в диалоговое окно запроса класса. Как сделать , чтобы при запуске класса последние введённые параметры запроса сразу появлялись (не приходилось бы нажимать на "Выбор" и "Ок")?

[Paul_ST]

Пробовали помещать переменную queryRun в список сохраняемых параметров (#localmacro.CurrentList1
dateBegin
, dateEnd

#endmacro)

[Paul_ST]

Сорри, ещё раз:
Пробовали помещать переменную queryRun в список сохраняемых параметров (#localmacro.CurrentList1
dateBegin
, dateEnd
, queryRun
#endmacro)
и сохранять, соответственно, методом pack(). Но возникает ошибка - некорректный тип параметра.

[Roman777]

1. queryRun нужно сгенерить в методе initParmDefault()
2. сделать сохранение этого queryRun в методе puck()
3. в методе unpack() сделать восстановление queryRun

[latvik]

метод pack() в студию!

[Paul_ST]

public container pack()
{
;
return [#CurrentVersion1, #CurrentList1];
}
, где #CurrentList1 - LocalMacro - см. в предыдущих сообщениях.

Кроме того return [#CurrentVersion1, #CurrentList1, queryRun]; тоже пытались делать

[Roman777]

нужно примерно так:

PHP код:

public container pack()
{
    return [#CurrentVersion, #CurrentList] + [queryRun.pack()] + [super()];
} 


[Владимир Максимов]

1) Метод ClassDeclaration. Определяешь 2 переменные

PHP код:

Query       queryMySample;
QueryRun queryRunMySample; 


2) Создай отдельный (новый) метод в котором будешь конструировать Query. Например, createQuery(). Этот метод формирует переменную типа Query, которую ты определил в ClassDeclaration как queryMySample

3) Создай еще один новый метод примерно такого содержания

PHP код:

public void makeQueryRun()
{
    ;
    if (! queryMySample)
    {
        this.createQuery();
    }
    queryRunMySample = new QueryRun(queryMySample);
} 


4) Перекрываешь метод QueryRun

PHP код:

public QueryRun queryRun()
{
    return queryRunMySample;
} 


5) Перекрываешь метод initParmDefault

PHP код:

// Переопределение данного метода нужно только при первом запуске
// когда у клиента еще не было Pack
void initParmDefault()
{
    super();
    this.makeQueryRun();
} 


6) Перекрываешь метод Pack

PHP код:

public container pack()
{
   return [#CurrentVersion, #CurrentList, queryRunMySample.query().pack()] + [super()];
} 


7) Перекрываешь метод UnPack

PHP код:

public boolean  unpack(container  packedClass)
{
    container       _base, packedQuery;
    boolean         _ret;
    Integer         _version    = conpeek(packedClass,1);
    ;

    switch (_version)
    {
        case #CurrentVersion:
            [_version, #CurrentList, packedQuery, _base] = packedClass;
            if (queryIsPackedOk(packedQuery))
            {
               queryMySample = new Query(packedQuery);
            }
            this.makeQueryRun();
            _ret = super(_base);
            break;
        default:
            _ret = false;
    }
    return _ret;
} 


Здесь queryIsPackedOk() - это метод класса Global. Вообще-то, он стандартный, но если его нет, то вот его код

PHP код:

/*MAN
Method to test a packed queryrun container is legal.
*/
static boolean queryIsPackedOk(PackedQueryRun packed)
{
    return sysQuery::isPackedOk(packed);
} 


AXAPTA 2.5 SP3

[Roman777]

а вот и Unpack() собственно:

PHP код:

public boolean unpack(container packedClass)
{
    container       _base;
    container       _packedQuery;
    boolean         _ret;
    Integer         _version    = conPeek(packedClass,1);

    switch (_version)
    {
        case #CurrentVersion:
            [_version, #CurrentList, _packedQuery, _base] = packedClass;
            if (!_packedQuery)
                return false;
            queryRun = new QueryRun(_packedQuery);
            _ret = super(_base);
            break;
        default:
            _ret = false;
    }
    return _ret;
} 


[Paul_ST]

Спасибо! Попробуем

[DreamCreator]

День Добрый!
Аналогично делал сохранение параметров в диалоге, код заработал только после того как в pack() и unpack() убрал вызовы родительских классов, по причине того что в них не было команды возврата. Класс наследник RunBaseBatch.
мой pack:

PHP код:

public container pack()
{
    return [#CurrentVersion, #CurrentList, queryRun.query().pack()];
} 


родительский (RunBase) pack:

PHP код:

abstract public container pack()
{
#if.never
    return [#CurrentVersion,#CurrentList];
#endif
} 


unpack по аналогии.